DisconnectedRecordset

				
'**************************************
' Name: DisconnectedRecordset
' Description:Get a disconnected recordset by ADODB Connection/Connectionstring and SQL selection
' By: MMeijer
'
' Inputs:ADODB Connection/Connectionstring and SQL selection
'
' Returns:A Disconnected ADODB.Recordset
'
' Assumes:Knowledge of SQL (can you make a selection?) and
ADODB.Recordset properties/methods.
'
' Side Effects:It Returns a ADODB.Recordset with 'Nothing' a ActiveConnection
'
'This code is copyrighted and has' limited warranties.Please see http://www.Planet-Source-Code.com/vb/scripts/ShowCode.asp?txtCodeId=7817&lngWId=4'for details.'**************************************

Function DisconnectedRecordset(byref vConn, byval sSql)
	Const adUseClient = 3
	Dim objRs, objConn, intConnectionStateBackup, intCursorLocationBackup
	
	'There's no way you can fetch a recordset by executing somethingelse then a selection query.
	If inStr(1,sSql,"select",vbTextCompare) = 0 Then
		Err.Raise 1,"SQL statement is not a selection."
		Exit Function
	End If 
	
	If isObject(vConn) Then '<-- I assume, ADODB.Connection
		'Bummer can't open the datasource
		If vConn.State <> 1 And vConn.ConnectionString = "" Then
			Err.Raise 1,"Unable to open a connection the datasource."
			Exit Function
		End If
		
		'A clientside cursor is needed, so let's close down connection object, 
		'and make it a connection with a clientside cursor
		intConnectionStateBackup = vConn.State '<-- backup state
		If vConn.state = 1 And vConn.CursorLocation <> adUseClient Then
			intCursorLocationBackup = vConn.CursorLocation
			vConn.Close
		End If
		If vConn.state <> 1 Then
			intCursorLocationBackup = vConn.CursorLocation
			vConn.CursorLocation = adUseClient
			vConn.Open
		End If
		Set objRs = vConn.Execute(sSql)
		Set objRs.ActiveConnection = Nothing
		
		If intConnectionStateBackup = 0 Then
			vConn.Close
		Else
			vConn.Close
			vConn.CursorLocation = intCursorLocationBackup
			vConn.Open
		End If
	Else '<-- I assume, ConnectionString
		Set objConn = Server.CreateObject("adodb.connection")
		objConn.CursorLocation = adUseClient
		objConn.Open vConn
		Set objRs = objConn.Execute(sSql)
		Set objRs.ActiveConnection = Nothing
		objConn.Close
		Set objConn = Nothing
	End If
	Set DisconnectedRecordset = objRs
	Set objRs = Nothing
End Function