DynamicArray Class

				
'**************************************
' Name: DynamicArray Class
' Description:Building a dynamic array of data, that is, an array that "knows" how to Add, Insert or Delete its element. This is a slightly modified (to accept objects as array elements) code from http://www.4guysfromrolla.com. Just use methods: .Add(data), .Insert(data) or .Delete(dataIndex)
' By: Miroslav Hibler
'
' Inputs:See code.
'
' Returns:An Array Object.
'
' Assumes:How to use classes in ASP.
'
'This code is copyrighted and has' limited warranties.Please see http://www.Planet-Source-Code.com/vb/scripts/ShowCode.asp?txtCodeId=7341&lngWId=4'for details.'**************************************

<%
'**************************************
' DynamicArray Class
'
' Author:	M. Hibler, July 5, 2001.
' Last change:	M. Hibler, March 15, 2002.
' Purpose:	Dynamically manipulate arrays of data
' Inputs:	See below
' Source:http://www.4guysfromrolla.com/webtech/code/array.class.asp.html
'**************************************
Class DynamicArray
'************* Properties *************
Private aData
'**************************************
'*********** Event Handlers ***********
Private Sub Class_Initialize()
	aData = Array(0)
End Sub
Private Sub Class_Terminate()
	ReDim aData(0)
End Sub
'**************************************
'************ Property Get ************
Public Property Get Data(iPos)
	If iPos < LBound(aData) or iPos > UBound(aData) then
		Exit Property 'Invalid range
	End If
	If IsObject(aData(iPost)) Then
		Set Data = aData(iPos)
	Else
		Data = aData(iPos)
	End If
End Property
Public Property Get DataArray()
	DataArray = aData
End Property
Public Property Get StartIndex()
	StartIndex = LBound(aData)
End Property
Public Property Get StopIndex()
	StopIndex = UBound(aData)
End Property
Public Property Get Count()
	Count = UBound(aData) - LBound(aData)
End Property
'**************************************
'************ Property Let ************
Public Property Let Data(iPos, varValue)
	'Make sure iPos >= LBound(aData)
	If iPos < LBound(aData) Then Exit Property
	If iPos > UBound(aData) then
		'We need to resize the array
		Redim Preserve aData(iPos)
	End If
	If IsObject(varValue) Then
		Set aData(iPos) = varValue
	Else
		aData(iPos) = varValue
	End If
End Property
'**************************************
'************** Methods ***************
Public Function Add(varValue)
	If IsObject(varValue) Then
		Set aData(UBound(aData)) = varValue
	Else
		aData(UBound(aData)) = varValue
	End If
	Add = UBound(aData)
	Redim Preserve aData(UBound(aData) + 1)
End Function
Public Function Insert(iPos, varValue)
	'Make sure iPos is within acceptable ranges
	If iPos > UBound(aData) then
	Call Add(varValue)
	Exit Function
	ElseIf iPos >= LBound(aData) then
		Dim iLoop
		For iLoop = UBound(aData) to iPos + 1 Step -1
			If IsObject(aData(iLoop - 1)) Then
				Set aData(iLoop) = aData(iLoop - 1)
			Else
				aData(iLoop) = aData(iLoop - 1)
			End If
		Next
		If IsObject(varValue) Then
			Set aData(iPos) = varValue
		Else
			aData(iPos) = varValue
		End If
		Insert = UBound(aData)
		Redim Preserve aData(UBound(aData) + 1)
	End If
End Function
Public Sub Delete(iPos)
	'Make sure iPos is within acceptable ranges
	If iPos < LBound(aData) or iPos > UBound(aData) then
		Exit Sub 'Invalid range
	End If
	Dim iLoop
	For iLoop = iPos to UBound(aData) - 1
		If IsObject(aData(iLoop + 1)) Then
			Set aData(iLoop) = aData(iLoop + 1)
		Else
			aData(iLoop) = aData(iLoop + 1)
		End If
	Next
	Redim Preserve aData(UBound(aData) - 1)
End Sub
Public Sub Flush()
	ReDim aData(0)
End Sub
'**************************************
	
End Class
%>