Base conversion 10 to N

				
--**************************************
-- Name: Base conversion 10 to N
-- Description:Converts a base10 numner to another base number (2-36 supported)
-- By: sp
--
-- Inputs:@Num, @Base
--
-- Returns:VARCHAR(255)
--
--This code is copyrighted and has-- limited warranties.Please see http://www.Planet-Source-Code.com/vb/scripts/ShowCode.asp?txtCodeId=1221&lngWId=5--for details.--**************************************

CREATE FUNCTION [dbo].[fn_Base10ToBaseN] (
	@Num BIGINT, 
	@Base TINYINT
)
RETURNS VARCHAR(255)
AS
-- ==============================================================================
-- Author:		Ian Marran marran@gmail.com
-- Description:	Converts a base10 numner to another base number (2-36 supported)
-- ==============================================================================
BEGIN
	DECLARE 
		@BaseChars VARCHAR(255),
		@ReturnString VARCHAR(255),
		@Done TINYINT,
		@Div BIGINT,
		@Rem BIGINT,
		@BaseChar CHAR(1)
	SET @BaseChars = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ'
	SET @ReturnString = ''
	SET @Done = 0
	IF (@Base BETWEEN 2 AND 36) AND (@Num >= 0)
	BEGIN
		WHILE @Done = 0
		BEGIN
			SELECT @Div = @Num / @Base, @Rem = @Num - (@Div * @Base)
			
			SET @BaseChar = SUBSTRING(@BaseChars, @Rem + 1, 1)
			SET @ReturnString = @BaseChar + @ReturnString
			SET @Num = @Div
			IF @Num = 0 
				SET @Done = 1
		END	
	END
	ELSE
		SELECT @ReturnString = 'Invalid Base or Number'
	--SELECT @ReturnString
	RETURN @ReturnString
END